TI Map Domain entity to EmailUrlInfo

Requête originale, sans modification.

let dt_lookBack = 1h; // Define the lookback period for email data as 1 hour
let ioc_lookBack = 14d; // Define the lookback period for threat intelligence data as 14 days
let EmailUrlInfo_ = EmailUrlInfo| where isnotempty(Url) or isnotempty(UrlDomain) // Filter for non-empty URLs or URL domains
| where TimeGenerated >= ago(dt_lookBack) // Filter for records within the lookback period
| extend Url = tolower(Url), UrlDomain = tolower(UrlDomain) // Convert URLs and domains to lowercase
| extend EmailUrlInfo_TimeGenerated = TimeGenerated; // Create a new column for the time generated
let EmailEvents_ = EmailEvents
| where TimeGenerated >= ago(dt_lookBack); // Filter email events within the lookback period
let TI_Urls = ThreatIntelIndicators
| where TimeGenerated >= ago(ioc_lookBack) // Filter threat intelligence indicators within the lookback period
| summarize arg_max(TimeGenerated, *) by Id, ObservableValue // Get latest record per Id FIRST
| where IsActive == true and ValidUntil > now() // THEN filter for active indicators that haven't expired
| extend IndicatorType = replace(@"\[|\]|\""", "", tostring(split(ObservableKey, ":", 0)))
| where isnotempty(IndicatorType) and IndicatorType == "url"
| extend Url = tolower(ObservableValue)
| where isnotempty(Url) // Filter for non-empty URLs
| join kind=innerunique (EmailUrlInfo_) on Url // Join with email URL info on URL
| extend Description = tostring(parse_json(Data).description)
| extend ActivityGroupNames = extract("ActivityGroup:([^,]+)", 1, tostring(parse_json(Data).labels))
| project EmailUrlInfo_TimeGenerated, Description, ActivityGroupNames, Id, ValidUntil, Confidence, Url, UrlLocation, NetworkMessageId; // Select relevant columns
let TI_Domains = ThreatIntelIndicators
| where TimeGenerated >= ago(ioc_lookBack) // Filter threat intelligence indicators within the lookback period
| where isnotempty(ObservableValue) // Filter for non-empty domain names
| extend DomainName = tolower(ObservableValue) // Convert domain names to lowercase
| where ObservableKey == "domain-name:value"
| summarize arg_max(TimeGenerated, *) by Id, ObservableValue // Get latest record per Id FIRST
| where IsActive == true // THEN filter for active indicators
| extend TrafficLightProtocolLevel = AdditionalFields.TLPLevel
| extend IndicatorId = tostring(split(Id, "--")[2]);
let TI_Domains_UrlInfo = TI_Domains
| project-reorder *, IsActive, Tags, TrafficLightProtocolLevel, DomainName, Type
| join kind=innerunique (EmailUrlInfo_) on $left.DomainName == $right.UrlDomain // Join with email URL info on domain name
| extend ExpirationDateTime = ValidUntil
| extend Description = Data.description
| extend ThreatType =  Data.type
| extend ConfidenceScore = Confidence
| extend ActivityGroupNames = replace_string(tostring(parse_json(tostring(Data.labels))[0]),"ActivityGroup:","")
| where ExpirationDateTime > now() // Filter for indicators that haven't expired
| project EmailUrlInfo_TimeGenerated, Description, ActivityGroupNames, IndicatorId, ThreatType, ExpirationDateTime, ConfidenceScore, UrlDomain, UrlLocation, NetworkMessageId; // Select relevant columns
union TI_Urls, TI_Domains_UrlInfo // Combine URL and domain threat intelligence data
| extend timestamp = EmailUrlInfo_TimeGenerated // Add a timestamp column
| join kind=inner (EmailEvents_) on NetworkMessageId // Join with email events on network message ID
| where DeliveryAction !has "Blocked" // Filter out blocked delivery actions
| extend Name = tostring(split(RecipientEmailAddress, '@', 0)[0]), UPNSuffix = tostring(split(RecipientEmailAddress, '@', 1)[0]); // Extract name and UPN suffix from recipient email address"