Detect DNS queries reporting multiple errors from different clients - Static threshold based (ASIM DNS Solution)

Original query, unchanged.

let lookback=1h;
let threshold = 2;
let errors = dynamic(['NXDOMAIN', 'SERVFAIL', 'REFUSED']); 
_Im_Dns(starttime=ago(lookback)) 
  | where EventResultDetails has_any (errors) 
  | summarize SrcIPs = make_set(SrcIpAddr, 100), Dvcs = make_set(Dvc, 100), ResourceIds = make_set(_ResourceId, 100) by DnsQuery, bin(TimeGenerated, 10min) 
  | where array_length(SrcIPs) >= threshold 
  | extend TotalIPs = array_length(SrcIPs),IPCountthreshold = threshold 
  | extend DomainName = strcat(split(DnsQuery, ".")[1], ".", split(DnsQuery, ".")[2])  
  | mv-expand SrcIPs  
  | extend SrcIP = tostring(SrcIPs)  
  | mv-expand Dvcs  
  | extend Dvc = tostring(Dvcs)  
  | mv-expand ResourceIds  
  | extend ResourceId = tostring(ResourceIds)  
  | extend Dvc = strcat(split(Dvc, ".")[0])
  | summarize Start=min(TimeGenerated), End=max(TimeGenerated) by SrcIP, Dvc, ResourceId, DnsQuery, DomainName, SrcIPs = tostring(SrcIPs), IPCountthreshold = threshold, TotalIPs
  | extend HostName = tostring(split(Dvc, ".")[0]), DomainIndex = toint(indexof(Dvc, '.'))
  | extend HostNameDomain = iff(DomainIndex != -1, substring(Dvc, DomainIndex + 1), Dvc)