Dataverse - New Dataverse application user activity type

Original query, unchanged.

let query_frequency = 1h;
let query_lookback = 14d;
let app_user_regex = "^[0-9A-Fa-f]{8}-[0-9A-Fa-f]{4}-[0-9A-Fa-f]{4}-[0-9A-Fa-f]{4}-[0-9A-Fa-f]{12}\\.com$";
let guid_regex = "([0-9A-Fa-f]{8}-[0-9A-Fa-f]{4}-[0-9A-Fa-f]{4}-[0-9A-Fa-f]{4}-[0-9A-Fa-f]{12})";
let application_users = DataverseActivity
    | where UserId !endswith "@onmicrosoft.com" and UserId != "Unknown"
    | summarize by UserId
    | where split(UserId, "@")[1] matches regex app_user_regex;
let historical_app_activity = application_users
    | join kind = inner (
        DataverseActivity
        | where TimeGenerated between(ago(query_lookback) .. ago(query_frequency))
        | summarize by UserId, EntityName, Message, InstanceUrl)
        on
        UserId;
let current_activity = application_users
    | join kind= inner (
        DataverseActivity
        | where TimeGenerated >= ago(query_frequency)
        | summarize by UserId, EntityName, Message, InstanceUrl)
        on
        UserId;
current_activity
| join kind = leftanti (historical_app_activity) on UserId, Message, EntityName, InstanceUrl
| summarize NewActivities = make_set(strcat(Message, " ", EntityName), 1000) by UserId, InstanceUrl
| extend
    AadUserId = extract(guid_regex, 1, tostring(split(UserId, "@")[0])),
    CloudAppId = int(32780)
| project
    UserId,
    NewActivities,
    InstanceUrl,
    AadUserId,
    CloudAppId